Generare ID Random

Per testare le prestazione delle query occorre avere le tabelle "cariche di dati". Per popolare le tabelle, può essere utile generare identificativi random.

Le funzioni riportate nello script seguente, servono rispettivamente per generare numeri interi casuali in un certo range, e per generare stringhe contenenti pseudo-identificativi di lunghezza variabile.

Ora, la domanda sorge spontanea: perchè implementare un gereratore di numeri random visto che esiste la funzione di sistema RAND()?
La risposta potrà sembrare banale, ma un generatore di identificativi, per essere comodo da usare, deve essere implementato come User Function... purtroppo SQL Server non consente di utilizzare RAND() all'interno di una User Function!

La funzione ETfRandom non è in grado di generare sequenze "perfettamente casuali", ma sufficentemente buone per i nostri scopi.

Se non viene specificato il parametro @RandLen nella funzione ETfGenRandomID, verrà generato un identificato di lunghezza variabile tra 4 e 16 caratteri.

Il generatore si basa su due stringhe, una per le consonanti ed una per le vocali e genera sillabe "leggibili".
Ovviamente è possibile cambiare le stringhe per ottenere identificativi di tipo diverso...

Di seguito riporto una sequenza di ID generati chiamando
dbo.[ETfGenRandomID](N'ID_', N'', NULL):
  ID_CESEFABUTOPILE
  ID_CADE
  ID_MIROVU
  ID_FALECISAZO
  ID_FEDICE
  ID_LADUZOSINEGA
  ID_BAFE
  ID_POTUBA
  ID_GEBIDIBAZANI
  ID_SEFACUVORILEDA

IF EXISTS (SELECT * FROM sys.objects WHERE object_id = OBJECT_ID(N'[dbo].[ETfRandom]') AND type in (N'FN', N'IF', N'TF', N'FS', N'FT'))
    DROP FUNCTION [dbo].[ETfRandom]
GO

CREATE FUNCTION [dbo].[ETfRandom](@UpperLimit int)
RETURNS int
AS
BEGIN
Declare @DT datetime2
Declare @RV int
    
    SET @DT = SYSDATETIME()
    WHILE SYSDATETIME() = @DT SET @DT = @DT
    
    SET @RV = @UpperLimit 
    WHILE @RV >= @UpperLimit 
        SET @RV = ABS((SIN(DATEPART(nanosecond, SYSDATETIME())) + 
                       COS(DATEPART(nanosecond, SYSDATETIME()))) * CAST((@UpperLimit) As Float))
        
    RETURN @RV
END
GO

IF EXISTS (SELECT * FROM sys.objects WHERE object_id = OBJECT_ID(N'[dbo].[ETfGenRandomID]') AND type in (N'FN', N'IF', N'TF', N'FS', N'FT'))
    DROP FUNCTION [dbo].[ETfGenRandomID]
GO

CREATE FUNCTION [dbo].[ETfGenRandomID](@Prefix As nvarchar(16),
                                       @Suffix As nvarchar(16),
                                       @RandLen bigint = NULL)
RETURNS nvarchar(64)
AS
BEGIN
    DECLARE @BaseID As nvarchar(64)
    DECLARE @Len As int

    SET @RandLen = ISNULL(@RandLen, 4+[dbo].[ETfRandom](12))
    IF @RandLen < 2 SET @RandLen = 2
    IF @RandLen > 64 SET @RandLen = 64
    
    SELECT @BaseID = N'', @Len = @RandLen / 2;
    
    WHILE @Len > 0
      SELECT @BaseID = @BaseID + SUBSTRING(N'BCDFGLMNPRSTVZBCDFGLSBCDS', [dbo].[ETfRandom](25)+1, 1) +
                                 SUBSTRING(N'AEIOUAEI', [dbo].[ETfRandom](8)+1, 1),
             @Len = @Len-1
    
    RETURN IsNull(@Prefix, N'') + @BaseID + IsNull(@Suffix, N'')
END
GO

/* -- Esempio di Utilizzo
SELECT dbo.[ETfGenRandomID](N'ID_', N'_1', 16)
SELECT dbo.[ETfGenRandomID](N'ID_', N'_1', NULL)
*/

Tutte le Utility